List of Articular Infinitives

Post Reply
Jonathan Robie
Posts: 3583
Joined: May 5th, 2011, 5:34 pm
Location: Durham, NC
Contact:

Re: List of Articular Infinitives

Post by Jonathan Robie » March 9th, 2015, 2:57 pm

Jonathan Robie wrote:That finds 249 instances, so I think we're missing some cases, I can look at that later. When I do that, I'll mail you a list of what I found.
OK, I just sent you the results of this query, which steps down recursively through word groups in the noun phrase that are clauses or verb phrases. (If anyone else wants to inspect the results, send me a PM or email.)

We're up to 295 now. But it may contain some false positives, I may need to restrict it further, I have only briefly scanned the results.

Code: Select all

declare function local:infinitives($wg as element(wg))
{
  $wg/w[@mood='infinitive' and @head='true']
  |  
  $wg[ 
    wg and
    count(wg) = count(wg[@class=('cl','vp')]) 
   ] / wg  !  local:infinitives(.)
};

for $np in //wg[@class='np']
where $np/w[1][@class='det' and @gender='neuter']
for $infinitive in local:infinitives($np)
return <match><infinitive>{ $infinitive }</infinitive><phrase>{ $np }</phrase></match>
0 x


ἐξίσταντο δὲ πάντες καὶ διηποροῦντο, ἄλλος πρὸς ἄλλον λέγοντες, τί θέλει τοῦτο εἶναι;
http://jonathanrobie.biblicalhumanities.org/

Jonathan Robie
Posts: 3583
Joined: May 5th, 2011, 5:34 pm
Location: Durham, NC
Contact:

Re: List of Articular Infinitives

Post by Jonathan Robie » March 9th, 2015, 10:02 pm

I posted the results of the above query with a stylesheet here:

http://ibiblio.org/bgreek/resources/que ... itives.xml

Caveat emptor ... I can see that it's missing some (e.g. Matthew 11:1), and there may be false positives. So the query still needs some help.
0 x
ἐξίσταντο δὲ πάντες καὶ διηποροῦντο, ἄλλος πρὸς ἄλλον λέγοντες, τί θέλει τοῦτο εἶναι;
http://jonathanrobie.biblicalhumanities.org/

Stephen Carlson
Posts: 2803
Joined: May 11th, 2011, 10:51 am
Location: Melbourne
Contact:

Re: List of Articular Infinitives

Post by Stephen Carlson » March 10th, 2015, 12:11 am

Jonathan Robie wrote:We're up to 295 now. But it may contain some false positives, I may need to restrict it further, I have only briefly scanned the results.
Three false positives (in the form of double counting) are where an articular δύνασθαι has an infinitive complement in 2 Cor 1:4, Eph 6:11, and Phil 3:21. Similarly, 2 Tim 3:15 governed by the articular participle τἀ δυνάμενα (the query should not select plural determiners); also in Mark 10:32 τὰ μέλλοντα αὐτῷ συμβαίνειν.

Same issue with τὸ δεῖν in Luke 18:1. Similarly, two more with δεῖ in 1 Thess 4:1, except that the syntactic structure is also misparsed (the interrogative is actually τὸ πῶς, see BDAG πῶς 1bα, 901b).

Another governed infinitive miscounted as an articular infinitive is χωρίζεσθαι in Acts 18:2 τὸ διατεταχέναι Κλαύδιον χωρίζεσθαι πάντας τοὺς Ἰουδαίους ἀπὸ τῆς Ῥώμης.

Rom 1:11 is misparsed: δέ should join its clause at a higher level than the preceding articular infinitive. Same with Rom 15:8. Something's going on with λατρεύειν in Luke 1:74, but I don't have the time to figure it out. These last three should be passed on to the maintainer of the syntax trees.
0 x
Stephen C. Carlson, Ph.D.
Melbourne, Australia

Jonathan Robie
Posts: 3583
Joined: May 5th, 2011, 5:34 pm
Location: Durham, NC
Contact:

Re: List of Articular Infinitives

Post by Jonathan Robie » March 10th, 2015, 10:03 am

Stephen Carlson wrote:
Jonathan Robie wrote:We're up to 295 now. But it may contain some false positives, I may need to restrict it further, I have only briefly scanned the results.
Three false positives (in the form of double counting) are where an articular δύνασθαι has an infinitive complement in 2 Cor 1:4, Eph 6:11, and Phil 3:21. Similarly, 2 Tim 3:15 governed by the articular participle τἀ δυνάμενα (the query should not select plural determiners); also in Mark 10:32 τὰ μέλλοντα αὐτῷ συμβαίνειν.

Same issue with τὸ δεῖν in Luke 18:1. Similarly, two more with δεῖ in 1 Thess 4:1, except that the syntactic structure is also misparsed (the interrogative is actually τὸ πῶς, see BDAG πῶς 1bα, 901b).

Another governed infinitive miscounted as an articular infinitive is χωρίζεσθαι in Acts 18:2 τὸ διατεταχέναι Κλαύδιον χωρίζεσθαι πάντας τοὺς Ἰουδαίους ἀπὸ τῆς Ῥώμης.
This is tremendously helpful to me. I have a shiny new toy to play with, and I want to figure out what it's good for, how best to use it, what the limitations are, and how it can be improved. I also want to understand the relative advantages of the three different models for New Testament Greek treebanks that are available as open data. This thread is a great opportunity to explore that (and after we're done here, maybe we can find other things to explore, one at a time and at a pace I can manage with my other responsibilities).

Do you like the format I used for reporting results? I'm slowly inching my way toward an environment that allows others do do queries and see results, and this is a format I can use fairly generically.

Except for the misparsing, these are all things I think I can fix in the query, probably later today if I can squeeze in some time during a work break, otherwise tomorrow. I have to work on these things opportunistically, in small blocks of time.

Incidentally, I'm more concerned about false negatives than false positives, because you can see the false positives and filter them out, but you don't see the false negatives. And I know there is at least one missing result, there could be others.
Stephen Carlson wrote:Rom 1:11 is misparsed: δέ should join its clause at a higher level than the preceding articular infinitive. Same with Rom 15:8. Something's going on with λατρεύειν in Luke 1:74, but I don't have the time to figure it out. These last three should be passed on to the maintainer of the syntax trees.
Thanks - I will enter bugs for these and the misparsing you mentioned above. I think all of these treebanks have been used more for analysis than for systematic queries at this point, and as we use them for queries, we will find - and fix - inconsistencies like this. The more we use them, the more we will fix.
0 x
ἐξίσταντο δὲ πάντες καὶ διηποροῦντο, ἄλλος πρὸς ἄλλον λέγοντες, τί θέλει τοῦτο εἶναι;
http://jonathanrobie.biblicalhumanities.org/

Jonathan Robie
Posts: 3583
Joined: May 5th, 2011, 5:34 pm
Location: Durham, NC
Contact:

Re: List of Articular Infinitives

Post by Jonathan Robie » March 10th, 2015, 3:31 pm

OK, I modified the function that finds infinitives in a word group. This was a simple fix - I no longer look for infinitives in subordinate clauses or phrases that function as objects or adverbially. You can see the results here:

http://ibiblio.org/bgreek/resources/que ... tives2.xml

I used a diff utility to see what changed, and the following false positives no longer appear:
  • Mark 10:32 : συμβαίνειν
  • Luke 01:73 : λατρεύειν
  • Acts 18:02 : χωρίζεσθαι
  • 2 Corinthians 01:04 : παρακαλεῖν
  • Ephesians 06:11 : στῆναι
  • Philippians 03:21 : ὑποτάξαι
  • 2 Timothy 03:15 : σοφίσαι
Let me show you the function that I changed, then walk you through it. It now looks like this:

Code: Select all

declare function local:infinitives($wg as element(wg))
{
  $wg/w[@mood='infinitive' and @head='true']
  |
  $wg[
    wg and
    count(wg) = count(wg[@class=('cl','vp')])
   ] / wg[not(@role='o' or @role='adv')]  !  local:infinitives(.)
};
Quick walk-through:
  • The function takes any word group, which is typically a noun phrase when first called. It is a recursive function, and calls itself to find infinitives in subclauses.

    Code: Select all

    declare function local:infinitives($wg as element(wg)) 
  • First, it returns all words in the current word group that are infinitives and head of the phrase in which they occur.

    Code: Select all

     $wg/w[@mood='infinitive' and @head='true']
  • The | is a "union operator", the result will include both results from the previous expression and results from the following expression
  • On the right-hand side of the union, we first check to see if the current word group (in the variable $wg) contains at least one wg element, and if all wgs it contains have the class 'cl' or the class 'vp'

    Code: Select all

      $wg[
        wg and
        count(wg) = count(wg[@class=('cl','vp')])
       ]
    If the condition is satisfied, this expression returns the current wg that is bound to $wg. If not, it returns an empty sequence.
  • Now we get to the expression that I changed to eliminate the false positives you mentioned. It used to select all word groups that are children of the current word group:

    Code: Select all

    / wg 
    I restricted it so that it does not select word groups that have the role of "object" or "adverbial":

    Code: Select all

    / wg[not(@role='o' or @role='adv')]
  • The ! operator says "execute the expression on the right once for each item on the left". The expression on the left returns word groups that do not have the role of "object" or "adverbial". In the expression on the right, the item for which it is being executed is denoted by ".". So this expression calls the local:infinitives() function recursively for each subordinate word group that is not being used as an object or adverbially.

    Code: Select all

    !  local:infinitives(.)
0 x
ἐξίσταντο δὲ πάντες καὶ διηποροῦντο, ἄλλος πρὸς ἄλλον λέγοντες, τί θέλει τοῦτο εἶναι;
http://jonathanrobie.biblicalhumanities.org/

Jonathan Robie
Posts: 3583
Joined: May 5th, 2011, 5:34 pm
Location: Durham, NC
Contact:

Re: List of Articular Infinitives

Post by Jonathan Robie » March 10th, 2015, 5:07 pm

Stephen Carlson wrote:Same issue with τὸ δεῖν in Luke 18:1. Similarly, two more with δεῖ in 1 Thess 4:1, except that the syntactic structure is also misparsed (the interrogative is actually τὸ πῶς, see BDAG πῶς 1bα, 901b).
Here are results from my latest fix, which does not keep looking for infinitives once they are found at a given level:

http://ibiblio.org/bgreek/resources/que ... tives3.xml

It gets rid of this false positive:
  • Luke 18:01 : προσεύχεσθαι
These two remain, they should be filtered out because they serve as the subject of another verb:
  • 1 Thessalonians 04:01 : περιπατεῖν
  • 1 Thessalonians 04:01 : ἀρέσκειν
I've reported bugs where you asked for them:

https://github.com/biblicalhumanities/g ... ent/issues

The query still fails to find Matthew 11:1, I'll look at that when I get a chance. If it's missing one valid instance, it is probably missing others.

Here's the local:infinitives() function as it now stands:

Code: Select all

declare function local:infinitives($wg as element(wg))
{
  let $infinitives := $wg/w[@mood='infinitive' and @head='true']
  return
    if ($infinitives)
    then $infinitives
    else
      $wg[
        wg and
        count(wg) = count(wg[@class=('cl','vp')])
      ] / wg[not(@role='o' or @role='adv')]  !  local:infinitives(.)
};
0 x
ἐξίσταντο δὲ πάντες καὶ διηποροῦντο, ἄλλος πρὸς ἄλλον λέγοντες, τί θέλει τοῦτο εἶναι;
http://jonathanrobie.biblicalhumanities.org/

Jonathan Robie
Posts: 3583
Joined: May 5th, 2011, 5:34 pm
Location: Durham, NC
Contact:

Re: List of Articular Infinitives

Post by Jonathan Robie » March 10th, 2015, 6:24 pm

Jonathan Robie wrote:These two remain, they should be filtered out because they serve as the subject of another verb:
  • 1 Thessalonians 04:01 : περιπατεῖν
  • 1 Thessalonians 04:01 : ἀρέσκειν
I need to figure out when I know not to look deeper. Informally, I should stop looking deeper once I have found whatever the article modifies. The following trick gets rid of just these two instances (compared to previous queries): if the head of a phrase is a word, stop looking deeper.

I found another variation that eliminates some false negatives too, I need time to compare results to see if I'm getting warmer. I'll look at the results and post tomorrow.
0 x
ἐξίσταντο δὲ πάντες καὶ διηποροῦντο, ἄλλος πρὸς ἄλλον λέγοντες, τί θέλει τοῦτο εἶναι;
http://jonathanrobie.biblicalhumanities.org/

Jonathan Robie
Posts: 3583
Joined: May 5th, 2011, 5:34 pm
Location: Durham, NC
Contact:

Re: List of Articular Infinitives

Post by Jonathan Robie » March 10th, 2015, 6:25 pm

Question: is this kind of "lab notes" thread interesting or tedious? We could do this elsewhere if it's flooding people, or I could do less on the forum and more in email, or we could decide what kinds of things are worth sharing.
0 x
ἐξίσταντο δὲ πάντες καὶ διηποροῦντο, ἄλλος πρὸς ἄλλον λέγοντες, τί θέλει τοῦτο εἶναι;
http://jonathanrobie.biblicalhumanities.org/

Stephen Carlson
Posts: 2803
Joined: May 11th, 2011, 10:51 am
Location: Melbourne
Contact:

Re: List of Articular Infinitives

Post by Stephen Carlson » March 10th, 2015, 6:31 pm

I'm in favor of doing this out in the open. Someone else might get interested and contribute, which won't happen in email. With the forum set-up, people have the choice of which threads they want to look at. As it now, B-Greek is already a low-volume forum, and low-volume fora risk extinction.
0 x
Stephen C. Carlson, Ph.D.
Melbourne, Australia

Stephen Carlson
Posts: 2803
Joined: May 11th, 2011, 10:51 am
Location: Melbourne
Contact:

Re: List of Articular Infinitives

Post by Stephen Carlson » March 10th, 2015, 9:17 pm

Jonathan Robie wrote:Do you like the format I used for reporting results? I'm slowly inching my way toward an environment that allows others do do queries and see results, and this is a format I can use fairly generically.
I would prefer to see some context too, e.g., the whole sentence and have the part matching the query in a different color like red or otherwise highlighted (not italics or expanded). But the output is fairly easy to scan quickly etc.
0 x
Stephen C. Carlson, Ph.D.
Melbourne, Australia

Post Reply