[Prev][Next][Index][Thread]

A 55 gallon drumshop?



Does anyone else collect used 55 gallon drums? 

This Spring, I put an ad in a local paper asking for some drums for a solar
project, and got a call from a food processing plant who offered 40 a month.
I've collected about 300 so far, about half steel and half plastic. They are
about 2' in diameter and 3' tall, and they weigh about 15 pounds empty and
450 pounds when full of water. The plastic ones should last a long time; the
steel ones might only last 20 years.

At the moment, I have 61 of them sitting in my backyard, which
amuses the neighbors. I'm wondering what to do with them...

Marge Wood of Abilene, TX, suggests building a "solar hot cube"...

>Nick, did you ever try the idea of building a "solar hot cube" in the
>form of a concrete porch with water modules (55 gal drums, old milk jugs,
>whatever) set into it and built on the sunny side of the house so it could
>look pretty and do something at the same time?

I guess pretty-looking is in the eye of the beholder... Why concrete,
I wonder? Why not just lay a piece of plastic on the ground to keep down
the dust, and put the drums on top. When they are filled with water,
they won't go anywhere. The cube needs insulation on all five sides,
but perhaps not much in the floor, since the cold water will probably stay at
the bottom, if the water temperature is above 39 F.

For the perimeter drumwall, you could lay 2 8' pressure treated 2 x 4s on the
ground, 2' apart, put 4 drums on top of them, standing up, fill them with
water, put two more plain 2 x 4s on top of those drums, so the outside edges
of the tops and bottoms of the drums are tangent to the outside edges of the
2 x 4s, fill those drums, lay 2 more 2 x 4s on top of those drums, and 2
more horizontal drums on top, to make a 8' tall x 8' long wall.

Then attach vertical 1 x 3s to the horizontal 2 x 4s every 4' along the wall
(3 of them for an 8' long wall) and attach some 4'x 8', 2" thick pieces of
Styrofoam to the 1 x 3s with some long decking screws. Paint the foamboard
with latex or acrylic paint. (Here you can be an artist :-) to make it last
a long time. Paint the south side a dark color, and attach a thin layer of
polycarbonate glazing to it, 3 or 4" away from the foamboard. Put a couple
of plastic film dampers at the top and the bottom of the south side. Build
3 more perimeter walls and fill the rest of the cube inside with 10 more
drums. Lay two pieces of foamboard on top and put a 10' x 10' piece of EPDM
rubber over that for a roof, with some rocks on top to hold it down (or old
tires, if you like the AE look :-) 

Voila. An 8' cube containing about 42 55 gallon drums full of water. The most
expensive thing is the 10 sheets of Styrofoam, $160 at 50 cents a square foot.
This would store the heat equivalent of about 10 gallons of oil at 130 F.
Enough for several days with no sun. I think it would make a dandy backup
house heater and water heater, if combined with a low-thermal-mass sunspace...

Where can you get some free 55 gallon drums near Abilene?

---

A solar heated workshop might be more interesting. Seems to me it could be
mostly built using the drums themselves, for structure and heat storage,
with some polyethylene film and Styrofoam walls. This might cost $500 or so,
for 12' x 16' of interior heated and lighted space...

Some ASCII sketches, not to scale...

	20'

 --------------------                  I might make this with a 9' ceiling,
|D      D h   |D|    |                 with 16' 2 x 4's running across
| . . .12'. . |D| .  |                 the ceiling on 4' centers, and 
|D        h   |D|    |                 a layer of 4' burlap attached to 
| . . . . . . |D| .  |                 the bottom of the 2 x 4's, and 
|         h16'|D|    | 20'             covered with a cement slurry.
|D. . . . . . |D| .  |                 Insulation might be leaves piled
|         h   |D|    |                 on top of the ceiling. The north
|D. . . . . . |D| .  |                 roof might be 1/4" exterior flakeboard
|         h   |D|    |                 over 16' 2 x 6s on 2' centers.
|D   D     D  |D|    |                 The south wall would be 20' long,
 ------door----------                  with 16' 2 x 6s every 4', with a
                                       single layer of 16' wide greenhouse
          h is a hinge                 poly film attached at the edges. 

           .   -  -  -  -  -  -  -
      /  . r.     r is a right angle
  14.7'.     .                         Polyethylene film for commercial
  /  .      6'.                        greenhouses costs about 5 cents
   .        *  . \                     per square foot, and comes in rolls
 ..........h..... 16'          14.7'   16' wide and 100' long. It lasts 
|D    .   .   |D|. \                   for 3 years, and it's recyclable.
|     . | .   | | .                    If it's covered on the outside in
|D    . 9'.   |D|  .                   the summer with a piece of 15 cent
|     . | .   | |   .                  per square foot greenhouse shadecloth
|D    .   .   |D|   a.                 it should last longer. In the winter 
 ---------------------------------     the shadecloth would hang vertically
                | 3.8'|                inside the sunspace. 

Some hinged panels could be raised up to admit some daylight and solar heat
into the room. The open position is shown above with a *.

A fan, might be used to draw down heat from the peak of the roof to heat up 
the room or the south wall drums. 

Greenhouse suppliers also sell inexpensive aluminum extrusions for attaching
layers of poly film to commercial greenhouses. If these are used to hold
the poly film, changing it every three years should only take an hour or so.

The north roof might be covered on top with EPDM rubber.

This might make a good doghouse, too. I'm a bit worried about burglars.
It might also have an insulated garage door.

10 'a BASIC solar shed design program,
20 'starting with an equation of form x^4 + Ax^3 + Bx^2 + Cx + D = 0
30 DS=16'shed depth (feet)
40 LSH=20'shed length (feet)
50 HS=9'shed height (feet)
60 LS=16'south wall height (feet)
70 A=-2*LS'constants related to geometry
80 B=LS^2-DS^2
90 C=2*LS*DS^2
100 D=DS^2*(HS^2-LS^2)
110 X=LS-HS'initial guess at clerestory slant height
120 XL=X
130 RES=X^4+A*X^3+B*X^2+C*X+D
140 X=X-.00001*RES
150 IF ABS(X-XL)>.00001 GOTO 120'iterate to 0.001% accuracy
160 DGF=180/(4*ATN(1))'to convert from radians to degrees
170 OPEN "shedout" FOR OUTPUT AS #1
180 PRINT#1,
190 PRINT#1, "Shed depth  (feet--NS):";DS
200 PRINT#1, "Shed length (feet--EW):";LSH
210 PRINT#1, "Shed height (feet):";HS
220 PRINT#1, "South wall slant height (feet):";LS
230 PRINT#1,
240 SSD=SQR((LS-X)^2-HS^2)
250 PRINT#1, "South wall slope (degrees):";DGF*ATN(HS/SSD)
260 RPH=LS*HS/(LS-X)
270 PRINT#1, "Roof peak height (feet):";RPH
280 PRINT#1,
290 LN=SQR(DS^2-X^2)
300 PRINT#1, "North wall slant height (feet):";LN
310 NWS = DGF*ATN(X/LN)
320 PRINT#1, "North wall slope (degrees):";NWS
330 PRINT#1,
340 PRINT#1, "Sunspace depth (feet):";SSD
350 PRINT#1, "South wall clerestory slant height (feet):";X
360 PRINT#1,
370 TP=.92'single layer poly film solar transmission
380 EIN=TP*1000*LSH*RPH
390 TA=32
400 PRINT#1, "Daily solar input (Btu):";EIN
410 PRINT#1, "Average ambient temp (F):";TA
420 RP=.8'R-value of single poly
430 RSW=10'(F-ft^2-hr/Btu)
440 PRINT#1, "R-value of shed walls:";RSW
450 RSC=20'((F-ft^2-hr/Btu)
460 PRINT#1, "R-value of shed ceiling:";RSC
470 POLYLOSSF=6*LS*LSH/RP'term for loss through poly film during day
480 SDRUMLOSSF=18*LSH*HS/RSW'term for loss through south drum wall at night
490 NDRUMLOSSF=24*LSH*HS/RSW'term for continuous loss through north drum wall
500 LOSSF=POLYLOSSF+SDRUMLOSSF+NDRUMLOSSF
510 TD=TA+EIN/LOSSF'steady-state drum water temp
520 RDN=RSW/(LSH*HS)'thermal resistance of north drumwall
530 RCEIL=RSC/(LSH*DS)'thermal resistance of shed ceiling
540 ROTHW=RSW/((LSH*2+DS)*HS)'thermal resistance of ENW walls
550 RP=1/(1/RCEIL+1/ROTHW)'parallel resistance of shed walls and ceiling
560 TR=TA+(TD-TA)*RP/(RDN+RP)'resistor divider calc
570 PRINT#1, "Steady-state room temp (F):";TR
580 PRINT#1, "Steady-state drum water temp (F):";TD
590 PRINT#1,
600 NSD=LSH/2*HS/3'number of 55 gallon drums in south wall
610 NOD=2*(LSH+DS)/4*HS/3'number of 55 gallon drums in other walls
620 ND=NSD+NOD
630 PRINT#1, "Total number of 55 gallon drums:";NOD
640 PRINT#1, "Number of drums in south wall:";NSD
650 CW=55*8*NSD
660 PRINT#1, "Weight of water in drumwall (pounds):";CW
670 SARD=2*(LSH*HS+LSH*2+HS*2)/RSW
680 RC=CW/SARD/24
690 PRINT#1, "RC time constant of drumwall (days):";RC
700 MGA=(25*NOD)/(RPH*LSH)
710 PRINT#1, "Thermal mass/glazing area ratio:";MGA
720 PRINT#1,
730 PRINT#1, "Days w/o sun  Drumwater temp"
740 PRINT#1,
750 FOR DAY=0 TO 7'days without sun
760 TDT=TA+(TD-TA)*EXP(-DAY/RC)
770 PRINT#1, DAY, TDT
780 NEXT DAY
790 CLOSE #1
 
Shed depth  (feet--NS): 16 
Shed length (feet--EW): 20 
Shed height (feet): 9 (3 drums high)
South wall slant height (feet): 16 
 
South wall slope (degrees): 67.09016 ["a" in the diagram above]
Roof peak height (feet): 14.7379 
 
North wall slant height (feet): 14.73758 
North wall slope (degrees): 22.91279 
 
Sunspace depth (feet): 3.803568 
South wall clerestory slant height (feet): 6.229272 
 
Daily solar input (Btu): 271177.4 
Average ambient temp (F): 32 
R-value of shed walls: 10 
R-value of shed ceiling: 20 
Steady-state room temp (F): 50.32511 
Steady-state drum water temp (F): 117.9244 
 
Total number of 55 gallon drums: 54 
Number of drums in south wall: 30 
Weight of water in drumwall (pounds): 13200 
RC time constant of drumwall (days): 11.55462 
Thermal mass/glazing area ratio: 4.580029 
 
Days w/o sun  Drumwater temp (F)
 
 0             117.9244 
 1             110.8007 
 2             104.2677 
 3             98.27622 
 4             92.78152 
 5             87.74236 
 6             83.12097 
 7             78.88274 

Nick