.TITLE	CTIMDI
	.IDENT	/V01/
	.ENABLE	LC
	.MCALL	GTIM$S
;
; This module forms part of the suite of Time Routines returning the
; current date in one of the following forms, or converting one form to
; another.
;	Form I	- Hours, Minutes, Seconds & Tenths of a Second
;	Form A	- ASCII HH:MM:SS.S
;	Form D	- Integer*4 seconds since midnight
;
; Author:	V01	15-Jul-80	Phil Stephensen-Payne
;
; Calling Sequence:
;
;	This subroutine is called via the standard FORTRAN calling sequence as:
;
;	CALL	CTIMDI (ISECS,TIMTBL [,STATUS])
; or
;	STATUS = CTIMDI (ISECS,TIMTBL)
;
; or
;	CALL	CTIMDI from MACRO-11 with
;		R5 = 0
;		R1 = Address of ISECS 
;		R2 = Address of TIMTBL
;		R0 = STATUS on output
;
;	Where:
;		ISECS	= Integer*4 seconds since midnight
;		TIMTBL	= 4-byte array for Hour, Minute, Second etc.
;		STATUS = Optional error return
;
; Errors returned:
;
;	STATUS = 0 if the operation was successful
;	       = -1 if a parameter error was detected
;	       = -2 if the time was invalid
;
; External references:
;
;	This module calls the subroutines PRMCHK 
;
;
CTIMDI::
	TST	R5		; Called directly from MACRO-11?
	BEQ	10$		; If eq yes - omit PRMCHK
;
; Specify number of parameters including error return.  R5 not affected.
;
	MOV	#3,R0		; Check Number of Parameters
	CALL	PRMCHK		;
	BCS	END		; If CS parameter error - exit at once
	TST	(R5)+		; Ignore number of parameters
	MOV	(R5)+,R1	; Get Address of Input
	MOV	(R5)+,R2	; Get Address for Output
;
10$:
	BIT	#1,R1		; Input address word-aligned?
	BNE	ERR2		; If NE no - parameter error
	CMP	2(R1),#1	; More than 65536 seconds?
	BHI	ERR		; If HI far too many - error
	BLO	20$		; If LO no - must be OK
	CMP	(R1),#20864.	; Yes - more than 86400?
	BHIS	ERR		; If HIS yes - error
;
20$:
	MOV	2(R1),R0	; Get high-order of value
	MOV	(R1),R1		; and the low-order
	ADD	#4,R2		; Set to end of output buffer
	CLRB	-(R2)		; No tenths
	DIV	#60.,R0		; Calculate seconds
	MOVB	R1,-(R2)	; Save seconds
	MOV	R0,R1		; Shift dividend down
	CLR	R0		; Clear high-order
	DIV	#60.,R0		; Calculate minutes
	MOVB	R1,-(R2)	; Save minutes
	MOVB	R0,-(R2)	; And hours
	CLR	R0		; Show success
;
END:
	RETURN
;
ERR:
	MOV	#-2,R0		; Invalid time
	RETURN			;
;
ERR2:
	MOV	#-1,R0		; Invalid parameters
	RETURN			;
	.END