Subject: Another drumwall water heater?

From: [email-masked] (Nick Pine)
Date: 22 Nov 1994 10:59:08 -0500

Here is another possible design for a drumwall that might be used
as a solar water heater.

It would use 30 drums, stacked up horizontally in a square array, 20'long x 6'
tall, perhaps behind 120 square feet of single pane glass, with a reflective
insulating shutter that lifts up from the top edge of the drums at a 45 degree
angle, and a reflective floor, inside a shed with a south wall made of,
eg Dynaglas.

It might look like this, not to scale:

.........................................      ...     .
.                                       .                . .
.                                       . south    east  . .   .
.                                       .               d.   .    .
.                                       .               y.  day.     .
......................................... ..   10'      n.      H...... . ..
. D . D .   .   .   .   .   .   .   .   .               a.      n.    . .
.........................................        <--S   g.      i...... .
.   .   .   .   .   .   .   .   .   .   . 6'            l.      g.    . . 6'
.........................................               a.      h...... .
.   .   .   .   .   .   .   .   .   .   .               s.      t.    . .
............................................................................
|                  20'                  |

The D's are drums, H is a horizontal hinge... Day and night shutter positions
are shown...

The numbers below again indicate drum water temperatures in degrees F, from
a small simulation using average Philadelphia weather conditions in January
(ambient temp, 32 degrees, 1200 Btu/day of sun on a south-facing wall,
T^4 heat loss) while extracting 100K Btu/day of domestic hot water from
the wall, using some food-grade, *lined* drums plumbed in series, on
the top row, pressurized with cold water on the way to the input of an
electric hot water in a house. It looks like 4 heat exhanger drums are enough.

Nick

10 'Todd Hall drumwall solar water heater?
20 'est. water temps for rectangular drumwall with 45 degree upward shutter
30 NH=10'number of horizontal drums
40 NV=3'number of vertical drums
50 ND=NH*NV'total number of drums
60 PI=4*ATN(1)'pi...
70 AD=(2*(23/2)^2*PI+23*PI*35)/144'drum area in ft^2
80 DIM T(NV, NH)'array of drum water temperatures
90 OPEN "drumout" FOR OUTPUT AS #1
100 'find steady-state temps
110 FOR R=1 TO NV'1 is top row, nv is bottom row...
120 FOR D=1 TO NH'1 is west drum in row...
130 T(R,D)=150'initialize drum temps
140 NEXT:NEXT
150 AREA=4*NH*NV'effective area of drumwall surface
160 SUNH=1.85*AREA*1000/ND/24'hourly sun energy/drum, inc. by shutter refl.
170 ES=15*5*3*8*55'energy for 15 5 min, 3 gpm, 110 degree showers/day
180 UH=ES/24'useful hourly heat output of drumwall
190 GLOSSF=1.74E-09*6*AREA/ND/24'factor for heat lost thru glazing per drum
200 AMRADF=(32+459)^4'factor for radiation from surroundings to drumwall
210 CP=55*8'thermal mass of a drum full of water
220 CLS
230 HMAX=192
240 PRINT #1,"Charging mode, with sun..."
250 PRINT "Charging mode, with sun..."
260 DT=.1'simulation time step
270 FOR H=0 TO HMAX+.01 STEP DT'hours of use
280 TECON=0'initialize total convection heat from below
290 LB=UH*DT/(T(1,NH)-55)'water moved thru system per time step
300 GOSUB 740
310 'adjust top drum row temperatures
320 FOR D=1 TO NH'drum number in top row
330 TD=T(NV,1)-T(1,D)'temp diff between top drum and lower drums
340 IF TD>0 THEN ECON=TD*AD ELSE ECON=0'convection heat from below
350 TECON=TECON+ECON'accumulate total hourly convection heat
360 HEATFLOW=(SUNH+ECON-((T(1,D)+459)^4-AMRADF)*GLOSSF)*DT
370 T(1,D)=T(1,D)+HEATFLOW/CP'adjust top row drum temp
380 IF T(1,D)>T(NV,1) THEN T(1,D)=T(NV,1)'limit upper drum temp
390 NEXT D
400 ECONA=TECON/(NH*(NV-1))'heatflow to top row from average drum
410 FOR R=2 TO NV'adjust bottom row temps
420 FOR D=1 TO NH
430 HEATFLOW=(SUNH-ECONA-((T(R,D)+459)^4-AMRADF)*GLOSSF)*DT
440 T(R,D)=T(R,D)+HEATFLOW/CP
450 NEXT D
460 NEXT R
470 IF INT(10*H+.05) MOD 480= 0 THEN GOSUB 800'print drum temp array
480 NEXT H
490 PRINT #1,
500 PRINT
510 PRINT #1,"Storage mode, with no sun..."
520 PRINT "Storage mode, with no sun..."
530 FOR H=DT TO 168+.01 STEP DT'hours of use
540 TECON=0'initialize total convection heat from below
550 'adjust top drum row temperatures
560 LB=UH*DT/(T(1,NH)-55)'water moved thru system per time step
570 GOSUB 740
580 FOR D=1 TO NH'drum number in top row
590 TD=T(NV,1)-T(1,D)'temp diff between top drum and lower drums
600 IF TD>0 THEN ECON=TD*AD ELSE ECON=0'convection heat from below
610 TECON=TECON+ECON'accumulate total convection heat
620 T(1,D)=T(1,D)+ECON*DT/CP
630 IF T(1,D)>T(NV,1) THEN T(1,D)=T(NV,1)'limit upper drum temp
640 NEXT D
650 IF INT(10*H+.05) MOD 240= 0 THEN GOSUB 800'print drum temp array
660 ECONA=TECON/(NH*(NV-1))'heatflow to top row from average drum
670 FOR R=2 TO NV'adjust bottom row temps
680 FOR D=1 TO NH
690 T(R,D)=T(R,D)-ECONA*DT/CP
700 NEXT D
710 NEXT R
720 NEXT H
730 END
740 T(1,1)=(LB*55+(CP-LB)*T(1,1))/CP'move 55 degree water into top left drum
750 IF T(1,1)<55 THEN T(1,1)=55'limit lower drum temp to 55
760 FOR D=2 TO NH'move water across top row
770 T(1,D)=(LB*T(1,D-1)+(CP-LB)*T(1,D))/CP'move water from top drum d-1-->d
780 NEXT D
790 RETURN
800 PRINT #1,
810 PRINT
820 PRINT #1,"Day:";INT(H/24+.01)
830 PRINT"Day:";INT(H/24+.01)
840 FOR RS=1 TO NV'display drum temperatures
850 FOR P=1 TO NH-1
860 PRINT #1,INT(T(RS,P)+.5);TAB(6*P);
870 PRINT INT(T(RS,P)+.5);TAB(6*P);
880 NEXT P
890 PRINT #1,INT(T(RS,NH)+.5)
900 PRINT INT(T(RS,NH)+.5)
910 NEXT RS
920 RETURN

Charging mode, with sun...
 
Day: 0 
 149  150   150   150   150   150   150   150   150   150 
 150  150   150   150   150   150   150   150   150   150 
 150  150   150   150   150   150   150   150   150   150 
 
Day: 2 
 95   120   136   146   152   156   156   156   156   156 
 156  156   156   156   156   156   156   156   156   156 
 156  156   156   156   156   156   156   156   156   156 
 
Day: 4 
 96   121   137   146   153   156   156   156   156   156 
 156  156   156   156   156   156   156   156   156   156 
 156  156   156   156   156   156   156   156   156   156 
 
Day: 6 
 96   122   137   147   153   157   157   157   157   157 
 157  157   157   157   157   157   157   157   157   157 
 157  157   157   157   157   157   157   157   157   157 
 
Day: 8 
 97   122   138   148   154   158   158   158   158   158 
 158  158   158   158   158   158   158   158   158   158 
 158  158   158   158   158   158   158   158   158   158 
 
Storage mode, with no sun...
 
Day: 1 
 89   112   128   138   145   149   149   149   149   149 
 149  149   149   149   149   149   149   149   149   149 
 149  149   149   149   149   149   149   149   149   149 
 
Day: 2 
 84   104   118   128   135   139   141   141   141   141 
 141  141   141   141   141   141   141   141   141   141 
 141  141   141   141   141   141   141   141   141   141 
 
Day: 3 
 80   97    110   119   125   129   132   132   132   132 
 132  132   132   132   132   132   132   132   132   132 
 132  132   132   132   132   132   132   132   132   132 
 
Day: 4 
 75   90    101   109   115   120   123   124   124   124 
 124  124   124   124   124   124   124   124   124   124 
 124  124   124   124   124   124   124   124   124   124 
 
Day: 5 
 71   83    93    100   106   110   113   115   115   115 
 115  115   115   115   115   115   115   115   115   115 
 115  115   115   115   115   115   115   115   115   115 
 
Day: 6 
 67   77    85    92    97    101   104   106   107   107 
 107  107   107   107   107   107   107   107   107   107 
 107  107   107   107   107   107   107   107   107   107 
 
Day: 7 
 64   72    78    84    88    91    94    97    99    99 <--hot water temp
 99   99    99    99    99    99    99    99    99    99    supplied to house
 99   99    99    99    99    99    99    99    99    99    after a week w/o
                                                            sun, in January